WORKDAY.INTL関数の使い方｜休みの曜日を指定して○営業日後の日付を求める

2024年6月29日2026年11月10日

Excel WORKDAY.INTL関数の使い方｜週末を指定して○営業日後の日付を求める

Excel の WORKDAY.INTL 関数は、休みの曜日と祝日を除いて、開始日から「○営業日後」の日付を求める関数です。土日休みだけでなく、日曜だけ休み・水曜と日曜が休みのような職場でも、納期や締め切りを計算できます。

この記事では、基本の式、週末の番号と 7 桁の文字での指定、祝日の一覧の除き方、7 桁を数値で書くと結果が1日ずれる落とし穴まで、実際の Excel の画面で説明します。

練習用Excelファイル（無料ダウンロード）

「基本」「本文の表」「週末の指定」「祝日の一覧」「よくある間違い」の5シートです。「基本」「本文の表」は記事内のツールと同じ表です。

無料Excelサンプルファイルダウンロード（.xlsx・11KB）

Excelファイル（.xlsx）／登録不要／数式・練習データ入り

WORKDAY.INTL関数の書き方

=WORKDAY.INTL(開始日,日数,[週末],[祝日])

引数	内容
開始日	数え始める日付です。開始日そのものは数えません。
日数	何営業日後かです。マイナスにすると、さかのぼった日付になります。
週末（省略可）	休みにする曜日です。番号（1＝土日など）か、7 桁の文字で指定します。省略すると土日です。
祝日（省略可）	休みにする日付のセルか範囲です。

基本の使い方：30営業日後の納期を求める

D2 に次の式を入力して、Enter キーを押します。

D2 に入れる式

=WORKDAY.INTL(A2,B2,1,C2)

A2　開始日（発注日）B2　日数（30日）1　週末（土日）C2　祭日（祝日）

ひとことで発注日から、土日と祝日を除いて30営業日後の日付を出す

式を分けて読むと（色は画像の枠と同じ）

開始日A2

いつから？

→ 発注日 2024/7/1

日数B2

何営業日後？

→ 30

週末1

休みの曜日は？

→ 1＝土曜と日曜

祭日C2

ほかの休みは？

→ 祝日 7/15

自分の表で使うときは
紫を 11 にすると日曜だけ、”0000011″ のように7桁で書くと休みの曜日を自由に指定できます。

答えは 2024/8/13 になります。式は、次の順に計算しています。

2024/7/1から数え始める
⇒ 土日と 7/15 は数えない
30営業日進める
⇒ 2024/8/13（火）

エクセルのWORKDAY.INTL関数で土日と祝日を除いた30営業日後の納期を求めた例

2024/7/1（月）から、土日と祝日の 7/15 を除いて 30 営業日後は 2024/8/13（火）でした（③）。結果がシリアル値（数値）で表示されたときは、セルの表示形式を日付にします。

ヒント：数値で表示されたら

45517 のような数値で表示されたときは、セルの表示形式を「日付」にします。

まず動かしてみよう｜この記事のサンプルをその場で試せます

ブラウザの上で、WORKDAY.INTL 関数の式を試せます。1つ目のタブは発注日から30営業日後の納期（練習用ファイルの「基本」シート）、2つ目のタブは週末の番号を変えた3つの例（「本文の表」シート）です。日数・週末の番号・祝日を書き換えると、結果の日付が変わります。

週末を番号で指定する

同じ式でも、週末の番号で休みの曜日が変わります（②）。2023/1/15 から土日と 1/20 を除いた 10 営業日後は 1/30、日曜だけ休みで 5/10 から 5 営業日さかのぼると（5/5 は休日）5/3 です（③）。

番号	休みの曜日	番号	休みの曜日
1（省略時）	土・日	11	日だけ
2	日・月	12	月だけ
3	月・火	13	火だけ
4	火・水	14	水だけ
5	水・木	15	木だけ
6	木・金	16	金だけ
7	金・土	17	土だけ

休みの曜日を7桁の文字で指定する

番号にない組み合わせは、月曜から日曜までの 7 桁の文字で指定します。休みの曜日を 1、営業日を 0 にします。たとえば水・土・日が休みなら "0010011" です。

エクセルのWORKDAY.INTL関数で週末を番号と7桁の文字で指定して結果を比べた例

2026/11/6（金）の 5 営業日後は、土日休み（1）なら 11/13、金土休み（7）や日曜だけ（11）なら 11/12 でした（②）。"0000011" は 1 と同じ 11/13、"0010011" は水曜も休みになるので 11/16 です（③）。

祝日の一覧を除く

=WORKDAY.INTL(E2,E3,1,$B$2:$B$3)

エクセルのWORKDAY.INTL関数で祝日の一覧を範囲で指定して除いた例と11月の営業日数

祝日は一覧にしておき、範囲で指定します。2026/10/30 から 10 営業日後は、祝日なしなら 11/13、文化の日（11/3）を除くと 11/16 になりました（③）。式をコピーしても一覧がずれないように $ で固定します。

期間の営業日数を数えるときは、同じ週末の指定と祝日の一覧で NETWORKDAYS.INTL を使います。2026 年 11 月は 19 日でした（④、NETWORKDAYS.INTL関数）。

よくある間違い

症状	考えられる原因	対処
結果が1日ずれる	7 桁を `0000011` のように数値で書き、11（日曜だけ）として扱われた	`"0000011"` と ” で囲んで文字にする。
#VALUE! になる	7 桁でない、または 7 日とも 1（休み）	月曜から日曜までの 7 桁にし、営業日を1日以上残す。
開始日が休日なのに数え方がおかしい	開始日は数えず、翌営業日から 1 日目と数える	土曜から 1 営業日後は月曜。日数 0 だと開始日がそのまま返る。
数字（46339 など）が表示される	結果はシリアル値	セルの表示形式を日付にする。
下の行で祝日が除かれない	祝日の範囲を $ で固定せずにコピーし、範囲がずれた	`$B$2:$B$3` のように固定する。

=WORKDAY.INTL(B1,5,0000011) と入力すると、Excel が式を =WORKDAY.INTL(B1,5,11) に書き換えてしまいました（①）。11 は「日曜だけ休み」なので、結果は 11/13 ではなく 11/12 です（②）。桁数が 6 桁、7 日とも休みの指定は #VALUE! でした（③）。土曜日から 1 営業日後は月曜日、日数 0 では土曜日のままです（④）。