エクセルでカレンダーを作るには、年と月のセルを用意し、1 日の日付から週の始まりまで戻した日付を並べます。曜日と日付は自動で合い、土日や祝日の色も条件付き書式で自動で付きます。この記事のカレンダーは、年と月を変えれば何年でも使える「万年カレンダー」です。
エクセルの万年カレンダーは、年と月のセルを変えるだけで、その月の日付が自動で並ぶカレンダーです。日付は DATE関数と WEEKDAY関数の式で出し、土日・祝日・今日の色は条件付き書式で自動で付けます。
この記事では、そのまま使える万年カレンダーのテンプレート(無料)と、自分で作るときの式とルールを、実際の画面で説明します。
万年カレンダーの使い方


「月」のセルは、▼から1〜12を選べます(データの入力規則)。

万年カレンダーの作り方
1. 日付を並べる式
左上のセル(A5)に、次の式を入れて、A5〜G10(7列×6行)にコピーします。表示形式は「d」(日だけ)にします。
=DATE($B$2,$D$2,1)-WEEKDAY(DATE($B$2,$D$2,1))+1+(ROW()-5)*7+(COLUMN()-1)
| 部分 | 意味 |
|---|---|
DATE($B$2,$D$2,1) | その月の1日 |
-WEEKDAY(…)+1 | 1日がある週の日曜日まで戻る |
+(ROW()-5)*7 | 下の行に行くごとに7日ずつ進む(5は先頭の行番号) |
+(COLUMN()-1) | 右の列に行くごとに1日ずつ進む |
6行あれば、どの月も入りきります。前の月・次の月の日付も表示されますが、次の条件付き書式で薄い灰色にします。
2. 色を付ける条件付き書式
A5〜G10 を選んで、「条件付き書式」→「新しいルール」→「数式を使用して、書式設定するセルを決定」で、次の5つのルールを作ります。

| ルール | 数式 | 書式 |
|---|---|---|
| ほかの月 | =MONTH(A5)<>$D$2 | 文字を薄い灰色(「条件を満たす場合は停止」にチェック) |
| 今日 | =A5=TODAY() | 薄い黄色で塗りつぶし |
| 祝日 | =COUNTIF(祝日!$A:$A,A5)>0 | 赤い文字+薄い赤で塗りつぶし |
| 日曜 | =WEEKDAY(A5)=1 | 赤い文字 |
| 土曜 | =WEEKDAY(A5)=7 | 青い文字 |
「ほかの月」のルールをいちばん上にして「条件を満たす場合は停止」にチェックを入れると、前後の月の土日・祝日には色が付かなくなります。条件付き書式のくわしい使い方は条件付き書式の使い方、祝日の色の付け方は祝日に色を付ける方法で説明しています。
3. 祝日の一覧
「祝日」シートに、内閣府が公表している「国民の祝日」の日付を入れておきます。テンプレートには 2024〜2027年の祝日(振替休日を含む)が入っています。

1 つの式で作る方法(Microsoft 365)
Microsoft 365 や Excel 2021 以降なら、左上のセルに式を 1 つ入れるだけで、カレンダー全体に日付が広がります。上の式をコピーした場合と、6 行 7 列のすべての日付が同じになりました。
=SEQUENCE(6,7,DATE($B$1,$D$1,1)-WEEKDAY(DATE($B$1,$D$1,1))+1)

| やりたいこと | 式の変えどころ |
|---|---|
| 月曜始まりにする | WEEKDAY(DATE($B$1,$D$1,1),2) にして、見出しを「月火水木金土日」にする |
| ほかの月の日付を空にする | =LET(d,SEQUENCE(…),IF(MONTH(d)=$D$1,d,"")) |
【実機で検証】カレンダーは何行必要か
2026 年と 2027 年の全部の月で、その月の日付が入る行数を数えました。
| 年 | 4 行 | 5 行 | 6 行 |
|---|---|---|---|
| 2026 年 | 2 月 | 上記以外 | 5 月・8 月 |
| 2027 年 | - | 上記以外 | 1 月・5 月・10 月 |
5 行分しか作らないと、6 行目を使う月の最後の日付が表示されません。はじめから 6 行分作っておきます。2026 年 2 月は 1 日が日曜で 28 日までなので、4 行で収まり、残りの 2 行はすべて次の月になりました。

入力ミスや空のセルで起きること
| 場面 | 結果 | 対処 |
|---|---|---|
| 月に 13 を入れる | エラーにならず 2027 年 1 月のカレンダーになる | 入力規則で 1〜12 に制限する |
| 月に 0 を入れる | 前の年の 12 月になる | 同じ |
| 2028 年 2 月 | 29 日まで正しく入る | - |
| ほかの月を “” で空にしたセル | WEEKDAY は #VALUE!。土日の色のルールは付かない | 空のセルに色が付かないので、そのままでよい |
日付を 1 つずつオートフィルで作ることもできますが、月や年が変わるたびに作り直しになります。式で作れば、年と月を変えるだけで済みます。
うまくいかないときの確認表
| 症状 | 考えられる原因 | 対処 |
|---|---|---|
| 日付が「46292」のような数字になる | 表示形式が「標準」 | 表示形式を「d」にする(日付の表示形式)。 |
| 祝日に色が付かない | 「祝日」シートにその年の日付がない | 祝日の日付を「祝日」シートのA列に追加する。 |
| 前の月の日曜も赤くなる | 「ほかの月」のルールが下にある | 「ほかの月」をいちばん上にして「条件を満たす場合は停止」にチェック。 |
あわせて読みたい:日付・カレンダーの関連記事
- エクセルで祝日に色を付ける方法
- エクセルで曜日に色を付ける方法
- エクセルで日付を簡単に入力する方法
- エクセルの日付の入力と計算
- エクセルの年間カレンダー2026
- エクセルで月間スケジュール表を作る方法
2027年の予定を月ごとに書き込むなら、2027年の月間カレンダー(無料テンプレート)もあわせてご覧ください。
カレンダーの月末に翌月の日付が出るときは、31日がない月の日付を非表示にする方法もあわせてご覧ください。
カレンダーに祝日を入れるなら、カレンダーに祝日を自動で入れる方法もあわせてご覧ください。

コメント