MENU

IFERROR関数の使い方|エラーを空白・0・「該当なし」にする・VLOOKUPの#N/A・IFNAとの違い

IFERROR関数の使い方|エラーを別の表示に置き換える

IFERROR関数は、式の結果がエラーのときだけ、別の表示に置き換える関数です。0 で割ったときの #DIV/0! や、VLOOKUP で見つからないときの #N/A を、「-」や「該当なし」、空白などにできます。

この記事では、IFERROR 関数の書き方から、割り算・VLOOKUP でのよくある使い方、IFNA との違い、IFERROR を使うときの注意点(入力ミスまで隠れる・空白に足すとエラー・0 にすると平均が変わる)まで、実際の Excel の画面で説明します。

練習用Excelファイル(無料ダウンロード)
「基本」「検索」「よくある間違い」と、記事内のツールと同じ「サンプル」の4シートです。
Excelファイル(.xlsx)/登録不要/数式・練習データ入り
目次

IFERROR関数の書き方(構文)

=IFERROR(値, エラーの場合の値)
引数意味
値ふだんの式(B2/C2、VLOOKUP(…) など)
エラーの場合の値エラーになったときに出すもの(”-“、”該当なし”、”” で空白、0 など)

エラーでないときは、1つ目の式の結果がそのまま出ます。Excel 2007 以降で使えます。

基本の使い方:0で割るエラーを「-」にする

手順:E2 に IFERROR の式を入れて、E6 までコピー

班ごとの金額を人数で割って「1人あたり」を出します。D列のようにそのまま割ると、人数が 0 の班は #DIV/0! になります。E2 に次の式を入力して Enter キーを押し❶、E6 までコピーします❷。

E2 に入れる式
=IFERROR(B2/C2,"-")
B2/C2 値(金額÷人数)"-" エラーの場合の値(エラーのときの表示)
ひとことで金額÷人数を計算し、エラー(#DIV/0!)になったときだけ「-」を表示する
式を分けて読むと(色は画像の枠と同じ)
値B2/C2
何を計算する?
→ 金額÷人数
エラーの場合の値"-"
エラーのときは?
→ 「-」と表示
自分の表で使うときは
青に「もとの式」、オレンジに「エラーのときの表示」を入れます。何も出さないなら "" です。例:見つからないときに「該当なし」と出す VLOOKUP=IFERROR(VLOOKUP(A2,$F$2:$G$50,2,FALSE),"該当なし")
  • どんなエラーも置きかえるので、式の入力ミスまで隠れてしまう点に注意します。
エクセルのIFERROR関数の式と、計算する式・エラーのときの表示を色分けした画面
エクセルのIFERROR関数の式と、計算する式・エラーのときの表示を色分けした画面

確認:人数が 0 の B班・D班だけ「-」になった

エクセルのIFERROR関数で、人数0の班の#DIV/0!が「-」になり、ほかの班は計算結果のままになったことを色で示した画面
エクセルのIFERROR関数で、人数0の班の#DIV/0!が「-」になり、ほかの班は計算結果のままになったことを色で示した画面

E2 から E6 まで、エラーになる班だけ – になりました❷。式は、1 行ずつ次の順に計算しています。

  1. まず 金額÷人数 を計算する
    ⇒ 人数が 0 の B班・D班は #DIV/0!
  2. IFERROR は、結果がエラーのときだけ “-“ に置きかえる
    ⇒ B班・D班は –、ほかの班は 250・300・150 のまま

まず動かしてみよう|この記事のサンプルをその場で試せます

ブラウザの上で IFERROR 関数を試せます。D3〜D7 は =IFERROR(B3/C3,"-") のように、金額を人数で割った「1人あたり」の式です。人数が 0 の班はエラーの代わりに「-」になります。黄色の人数を書き換えると、結果もその場で変わります。練習用ファイルの「サンプル」シートと同じ表です。

VLOOKUPの#N/Aを「該当なし」にする

いちばんよく使うのが、VLOOKUP で見つからないときの #N/A を消す使い方です。商品の一覧に無いコード「B09」は、VLOOKUP だけだと #N/A(②)、IFERROR で囲むと「該当なし」(③)になりました。

=IFERROR(VLOOKUP(D3,$A$2:$B$5,2,FALSE),"該当なし")
エクセルのIFERROR関数でVLOOKUPのNAを該当なしにした例とXLOOKUPの4つ目の引数の例
エクセルのIFERROR関数でVLOOKUPのNAを該当なしにした例とXLOOKUPの4つ目の引数の例

XLOOKUP 関数なら IFERROR を使わなくても、4つ目の引数に「見つからないときの表示」を書けます。=XLOOKUP(D3,$A$2:$A$5,$B$2:$B$5,"該当なし") も「該当なし」でした(④、XLOOKUP関数の使い方)。

IFERROR を使うときの注意点(よくある間違い)

エクセルのIFERROR関数で入力ミスが隠れる例と空白に足すとVALUEになる例と平均が変わる例
エクセルのIFERROR関数で入力ミスが隠れる例と空白に足すとVALUEになる例と平均が変わる例
症状考えられる原因対処
式を間違えているのに気づかないIFERROR は #NAME? など入力ミスのエラーも隠す式ができてから最後に IFERROR で囲む。#N/A だけ消したいなら IFNA。
IFERROR の結果に足し算すると #VALUE! になるエラーの代わりに “” (空の文字)を出している足し算は SUM を使う、またはエラーの代わりを 0 にする。
平均が思ったより低いエラーの代わりに 0 を出して、0 も平均に入ったエラーの代わりを “” にして AVERAGE で平均する。

試したところ、関数名を「SUMM」と打ち間違えた =IFERROR(SUMM(B2:B6),"") は、エラーが出ずに空白になりました(①)。=IFERROR(B3/C3,"")+1 は #VALUE! です(②)。エラーを 0 にした平均は 140.0、空白(””)にした =AVERAGE(IFERROR(B2:B6/C2:C6,"")) は、割り算できた3班だけの平均で 233.3 でした(③)。

IFNA関数との違い

IFNA 関数は #N/A のときだけ置き換えます。0 で割る #DIV/0! はそのまま残り、試したところ =IFNA(B3/C3,"-") は #DIV/0! でした(④)。VLOOKUP の「見つからない」だけを消して、ほかのエラーには気づけるようにしたいときは IFNA が向いています(IFNA関数の使い方)。

関数置き換えるエラー
IFERRORすべてのエラー(#DIV/0!・#N/A・#VALUE!・#NAME? など)
IFNA#N/A だけ

よくある質問

エラーがいくつあるか数えたいときは?

=SUMPRODUCT(--ISERROR(D2:D6)) のように ISERROR 関数を使います。この記事の表では 2 でした(ISERROR関数の使い方)。

エラーの種類ごとの意味と直し方は?

#DIV/0!・#N/A・#VALUE!・#REF! などの意味は エラー値の一覧と直し方でまとめています。IFERROR で隠す前に、原因を確かめておくと安心です。

印刷するときだけエラーを表示したくないときは?

式を変えずに、ページ設定で印刷時のエラーの表示を変える方法があります(0・エラーを表示しない方法)。

IFERROR関数で、エラーを空白にするには?

エラーの場合の値に "" を指定します。=IFERROR(B3/C3,"") のように書くと、エラーのときだけ空白になります。ただし、この結果に足し算をすると #VALUE! になるので、足し算は SUM を使います。

練習用Excelファイル(無料ダウンロード)
この記事の例がすべて入った練習用のファイルです。
Excelファイル(.xlsx)/登録不要/数式・練習データ入り

あわせて読みたい:エラー処理の関連記事

エラーを無視して合計・平均を出すなら、AGGREGATE関数の使い方もあわせてご覧ください。

よかったらシェアしてね!
  • URLをコピーしました!
  • URLをコピーしました!

この記事を書いた人

目次