エクセルで時給計算をする方法|時給×時間の計算式・休憩を引く・15分単位・月の合計【実機で解説】

エクセルで時給計算をする方法|時給×時間の計算式・休憩を引く・15分単位・月の合計【実機で解説】

時給から給与を計算する式は =(退勤-出勤-休憩)*24*時給 です。時刻の引き算で出した勤務時間に 24 を掛けて「○時間」という数にしてから、時給を掛けます。

エクセルの時刻は「1 日=1」という数で入っているので、24 を掛けないと金額がとても小さくなります。この記事では、勤務時間の出し方、その日の給与、15 分単位の切り捨て、月の合計を、実際の Excel で確かめた結果で説明します。

練習用Excelファイル(無料ダウンロード)
出勤・退勤・休憩の表と、この記事の時給計算の式をまとめた練習ファイルです。時刻や時給を書き換えると給与が変わります。
Excelファイル(.xlsx)/登録不要/数式・練習データ入り
目次

時給計算の式

=(退勤-出勤-休憩)*24*時給
部品意味
退勤-出勤-休憩休憩を引いた勤務時間。時刻のまま(7:00 など)で出ます
*24時刻を「7」「4.75」のような時間の数に直す
時給1 時間あたりの金額。1 つのセルに入れて $ で固定して参照する
FLOOR15 分単位などに切り捨てるときに使う

出勤・退勤・休憩は「9:00」「0:45」のように、コロンで区切った時刻の形で入れます。

1. 勤務時間を出す(退勤−出勤−休憩)

退勤から出勤を引き、さらに休憩を引きます。I2 に式を入れて下へコピーします。

=C2-B2-D2
エクセルで退勤から出勤と休憩を引いて勤務時間を計算した画面
エクセルで退勤から出勤と休憩を引いて勤務時間を計算した画面

11/2 は 7:00、11/4 は 4:45、11/5 は 8:10 でした。休憩が 0:00 の 11/6 は、退勤−出勤そのままの 4:40 です。

時間の引き算は 時間の足し算・引き算でくわしく説明しています。

2. その日の給与を出す(勤務時間×24×時給)

勤務時間に 24 と時給を掛けます。時給は F2 に入れて、下へコピーしてもずれないように $F$2 と $ で固定します。

=(C2-B2-D2)*24*$F$2
エクセルで勤務時間に24と時給を掛けてその日の給与を計算した画面
エクセルで勤務時間に24と時給を掛けてその日の給与を計算した画面

時給 1,200 円で、7 時間の 11/2 は 8,400、4 時間 45 分の 11/4 は 5,700、8 時間 10 分の 11/5 は 9,800 でした。

分の端数もそのまま計算されています。円未満が出るときは、表示形式ではなく ROUND などの関数で丸めます。丸め方は勤め先の決まりに合わせてください。

3. 15分単位に切り捨ててから計算する(FLOOR)

勤務時間を 15 分単位に切り捨ててから時給を掛ける形です。勤務時間に 1440 を掛けて「分」に直し、FLOOR で 15 の倍数に切り捨て、60 で割って時間に戻します。

=FLOOR(ROUND((C2-B2-D2)*1440,0),15)/60*$F$2
エクセルのFLOOR関数で勤務時間を15分単位に切り捨ててから時給を掛けた画面
エクセルのFLOOR関数で勤務時間を15分単位に切り捨ててから時給を掛けた画面

8 時間 10 分の 11/5 は 8 時間として 9,600、4 時間 40 分の 11/6 は 4 時間 30 分として 5,400、6 時間 55 分の 11/9 は 6 時間 45 分として 8,100 でした。ちょうど割り切れる 11/2 は 8,400 のままです。

ROUND で分を整数にしているのは、時刻の計算にごく小さな誤差が出て、15 分少なく切り捨てられることがあるためです(下の検証)。何分単位で計算するか、切り捨てるかどうかは勤め先の決まりで違います。

4. 月の合計を出す

勤務時間をまとめて足してから、24 と時給を掛けます。SUMPRODUCT は、行ごとの「退勤−出勤−休憩」を計算して合計します。

=SUMPRODUCT(C2:C6-B2:B6-D2:D6)*24*F2
エクセルのSUMPRODUCT関数で勤務時間を合計して時給を掛け給与の合計を計算した画面
エクセルのSUMPRODUCT関数で勤務時間を合計して時給を掛け給与の合計を計算した画面

合計は 37,800 でした。2 の例の 5 日分を足した金額と同じです。その日の給与の列があるなら、=SUM(I9:I13) のように SUM で足しても出せます。

【実機で検証】時給計算でつまずくところ

エクセルの時給計算で24を掛け忘れたときや合計時間の表示や15分単位の切り捨ての誤差を確かめた画面
エクセルの時給計算で24を掛け忘れたときや合計時間の表示や15分単位の切り捨ての誤差を確かめた画面
ためしたこと式結果
24 を掛けずに時給を掛ける(7 時間)=(時給計算!C2-時給計算!B2-時給計算!D2)*時給計算!F2350
24 を掛ける(7 時間)=(時給計算!C2-時給計算!B2-時給計算!D2)*24*時給計算!F28,400
5 日分の勤務時間の合計を h:mm で表示=TEXT(SUMPRODUCT(時給計算!C2:C6-時給計算!B2:B6-時給計算!D2:D6),"h:mm")7:30
同じ合計を [h]:mm で表示=TEXT(SUMPRODUCT(時給計算!C2:C6-時給計算!B2:B6-時給計算!D2:D6),"[h]:mm")31:30
13:15〜15:15(2 時間)を ROUND なしで 15 分単位に=FLOOR((TIME(15,15,0)-TIME(13,15,0))*1440,15)105
同じ時刻を ROUND ありで 15 分単位に=FLOOR(ROUND((TIME(15,15,0)-TIME(13,15,0))*1440,0),15)120

24 を掛けずに時給を掛けると 350 になりました。正しくは 8,400 です。7:00 という時刻の中身は「7÷24」という小さな数なので、24 を掛けて 7 に直してから時給を掛けます。

5 日分の勤務時間の合計は、表示形式が h:mm だと 7:30、[h]:mm だと 31:30 でした。h:mm は 24 時間を超えた分を表示しません。合計時間のセルは [h]:mm にします(時間の表示形式)。

13:15 から 15:15 までのちょうど 2 時間を、ROUND なしで 15 分単位に切り捨てると 105 分になりました。120 分のはずが 15 分少なくなっています。時刻の計算にごく小さな誤差があり、120 にわずかに届かない数になっているためです。ROUND で分を整数にしてから切り捨てると 120 分で、正しく出ます。

よくある質問

残業や深夜の時間を分けて計算するには?

定時を超えた時間や深夜の時間を別の列に出してから、それぞれに時給を掛けます。時間の分け方は 残業時間の計算で説明しています。割増の率は勤め先の決まりを確かめてください。

退勤が翌日になる(22:00〜翌 2:00 など)ときは?

退勤の時刻のほうが小さくなるので、そのまま引くとマイナスになります。退勤に 1(1 日)を足して =(C2+1-B2-D2)*24*$F$2 とします。日をまたぐ時間の計算は 時間の足し算・引き算で説明しています。

1 か月分の勤怠表から給与まで出したいです。

日付・出勤・退勤・休憩を 1 か月分ならべた表は 勤怠表の作り方(無料テンプレート)で配布しています。

練習用Excelファイル(無料ダウンロード)
この記事の例をまとめた練習ファイルです。
Excelファイル(.xlsx)/登録不要/数式・練習データ入り

あわせて読みたい:関連記事

よかったらシェアしてね!
  • URLをコピーしました!
  • URLをコピーしました!

この記事を書いた人

目次